               /**  Hypergeometric functions - 5  **/
 
                 /**  5.  Functional relations  **/
 
/*A: S.Wolfram */
/*S: California Institute of Technology */
/*D: July 1981 */
/*U: March 1985 */

 
SHg_:Ldist
 
 
                /**  Elementary transformations  **/
 
 
SHg[5,0]:      Hg[$a,$b,$c,$z] -> Hg[$b,$a,$c,$z]
 
 
                /**  Linear transformations  **/
 
 
SHg[5,1]:       Hg[$a,$b,$c,$z] -> (1-$z)^($c-$b-$a) Hg[$c-$a,$c-$b,$c,$z]
 
SHg[5,2]:       Hg[$a,$b,$c,$z] -> Hg[$a,$c-$b,$c,$z/($z-1)]/(1-$z)^$a
 
SHg[5,3]:       Hg[$a,$b,$c,$z] -> Gamma[$c] Gamma[$c-$a-$b]\
                        /(Gamma[$c-$a] Gamma[$c-$b]) Hg[$a,$b,$a+$b-$c+1,1-$z]\
                        +(1-$z)^($c-$a-$b) Gamma[$c] Gamma[$a+$b-$c]\
                        /(Gamma[$a] Gamma[$b]) Hg[$c-$a,$c-$b,$c-$a-$b+1,1-$z]
 
SHg[5,4]:       Hg[$a,$b,$c,$z] -> 1/(-$z)^$a Gamma[$c] Gamma[$b-$a]\
                        /(Gamma[$b] Gamma[$c-$a]) Hg[$a,1-$c+$a,1-$b+$a,1/$z]\
                        +1/(-$z)^$b Gamma[$c] Gamma[$a-$b]\
                        /(Gamma[$a] Gamma[$c-$b]) Hg[$b,1-$c+$b,1-$a+$b,1/$z]
 
SHg[5,5]:       Hg[$a,$b,$c,$z] ->\
                        1/(1-$z)^$a Gamma[$c] Gamma[$b-$a]/(Gamma[$b]\
                         Gamma[$c-$a]) Hg[$a,$c-$b,$a-$b+1,1/(1-$z)]\
                        +1/(1-$z)^$b Gamma[$c] Gamma[$a-$b]/(Gamma[$a]\
                         Gamma[$c-$b]) Hg[$b,$c-$a,$b-$a+1,1/(1-$z)]
 
 
SHg[5,6]:       Hg[$a,$b,$c,$z] -> 1/$z^$a Gamma[$c] Gamma[$c-$a-$b]/\
                (Gamma[$c-$a] Gamma[$c-$b]) Hg[$a,$a-$c+1,$a+$b-$c+1,1-1/$z]\
                +(1-$z)^($c-$a-$b) $z^($a-$c) Gamma[$c] Gamma[$a+$b-$c]\
                /(Gamma[$a] Gamma[$b]) Hg[$c-$a,1-$a,$c-$a-$b+1,1-1/$z]
 
 
                /**  Quadratic transformations  **/
 
 
SHg[5,7]:     Hg[$a,$b,2 $b,$z] -> \
                (1-$z)^(-$a/2) Hg[$a/2,$b-$a/2,$b+1,$z^2/(4 $z-4)]
 
SHg[5,8]:     Hg[$a,$b,2 $b,$z] -> \
                (1-$z/2)^(-$a) Hg[$a/2,$a/2+1/2,$b+1/2,$z^2/(2-$z)^2]
 
SHg[5,9]:     Hg[$a,$b,2 $b,$z] -> (1/2+Sqrt[1-$z]/2)^(-2 $a)\
                Hg[$a,$a-$b+1/2,$b+1/2,((1-Sqrt[1-$z])/(1+Sqrt[1-$z]))^2]
 
SHg[5,10]:    Hg[$a,$b,2 $b,$z] -> (1-$z)^(-$a/2) \
                Hg[$a,2 $b-$a,$b+1/2,-(1-Sqrt[1-$z])^2/(4 Sqrt[1-$z])]
 
 
SHg[5,11]:    Hg[$a,$b_=$b=$a+1/2,$c,$z] -> (1/2+Sqrt[1-$z]/2)^(-2 $a)\
                Hg[2 $a,2 $a-$c+1,$c,(1-Sqrt[1-$z])/(1+Sqrt[1-$z])]
 
SHg[5,12]:    Hg[$a,$b_=$b=$a+1/2,$c,$z] -> (1-Sqrt[$z])^(-2 $a)\
                Hg[2 $a,$c-1/2,2 $c-1,-2 Sqrt[$z]/(1-Sqrt[$z])]
 
SHg[5,13]:    Hg[$a,$b_=$b=$a+1/2,$c,$z] -> (1+Sqrt[$z])^(-2 $a)\
                Hg[2 $a,$c-1/2,2 $c-1,2 Sqrt[$z]/(1+Sqrt[$z])]
 
SHg[5,14]:    Hg[$a,$b_=$b=$a+1/2,$c,$z] -> 1/(1-$z)^$a\
                Hg[2 $a,2 $c-2 $a-1,$c,(Sqrt[1-$z]-1)/(2 Sqrt[1-$z])]
 
SHg[5,15]:    Hg[$a,$b,$a+$b+1/2,$z] ->\
                Hg[2 $a,2 $b,$a+$b+1/2,1/2-Sqrt[1-$z]/2]
 
SHg[5,16]:    Hg[$a,$b,$a+$b+1/2,$z] -> (1/2+Sqrt[1-$z]/2)^(-2 $a)\
                Hg[2 $a,$a-$b+1/2,$a+$b+1/2,(Sqrt[1-$z]-1)/(Sqrt[1-$z]+1)]
 
SHg[5,17]:    Hg[$a,$b,$a+$b-1/2,$z] ->\
                1/Sqrt[1-$z] Hg[2 $a-1,2 $b-1,$a+$b-1/2,1/2-Sqrt[1-$z]/2]
 
SHg[5,18]:    Hg[$a,$b,$a+$b-1/2,$z] -> (1/2+Sqrt[1-$z]/2)^(1-2 $a)/Sqrt[1-$z]\
                Hg[2 $a-1,$a-$b+1/2,$a+$b-1/2,(Sqrt[1-$z]-1)/(Sqrt[1-$z]+1)]
 
 
SHg[5,19]:    Hg[$a,$b,$a-$b+1,$z] ->\
                1/(1+$z)^(2 $a) Hg[$a/2,$a/2+1/2,$a-$b+1,4 $z/(1+$z)^2]
 
SHg[5,20]:    Hg[$a,$b,$a-$b+1,$z] -> (1+Sqrt[$z])^(-2 $a)\
                Hg[$a,$a-$b+1/2,2 $a-2 $b+1,4 Sqrt[$z]/(1+Sqrt[$z])^2]
 
SHg[5,21]:    Hg[$a,$b,$a-$b+1,$z] -> (1-Sqrt[$z])^(-2 $a)\
                Hg[$a,$a-$b+1/2,2 $a-2 $b+1,-4 Sqrt[$z]/(1-Sqrt[$z])^2]
 
SHg[5,22]:    Hg[$a,$b,$a-$b+1,$z] -> \
                1/(1-$z)^$a Hg[$a/2,$a/2-$b+1/2,$a-$b+1,-4 $z/(1-$z)^2]
 
 
SHg[5,23]:    Hg[$a,$b,($a+$b+1)/2,$z] -> \
                Hg[$a/2,$b/2,($a+$b+1)/2,-4 $z($z-1)]
 
SHg[5,24]:    Hg[$a,$b,$a/2+$b/2+1/2,$z] -> 1/(1-2 $z)^$a \
                Hg[$a/2,$a/2+1/2,$a/2+$b/2+1/2,4 $z ($z-1)/(1-2 $z)^2]
 
 
SHg[5,25]:    Hg[$a,1-$a,$c,$z] -> \
                (1-$z)^($c-1)Hg[$c/2-$a/2,$c/2+$a/2-1/2,$c,4 $z-4 $z^2]
 
SHg[5,26]:    Hg[$a,1-$a,$c,$z] -> (1-$z)^($c-1) (1-2 $z)^($a-$c)\
                Hg[$c/2-$a/2,$c/2-$a/2+1/2,$c,4 $z($z-1)/(1-2 $z)^2]
 
